No, change several names, sorry ^^

Ah, well you have a few options, there. The section that checks which token you have is this:
push hl
ld hl, $C8*2
or a
sbc hl, de
add hl, de ;essentially, cp DE
pop hl
This returns Z if you have the right token, NZ if you don't. If you are changing a lot of token names, you would be better off using a look-up table. In your case, though, I think you are only changing a few tokens, so you can try to test like this:
ld hl, tokenHook
ld de, smallEditRam ;nothing touches this, ever
ld bc, tokenHookEnd-tokenHook
ldir ;copy it to a place where it won't get destroyed

ld a, 1 ;1 means ram
ld hl, smallEditRam
bcall(_enableTokenHook)
ret

tokenHook:
.db $83 ;necessary for hooks, indicates that it hasn't been overwritten
push hl
;Test the first token
;DE contains the token
ld hl, $C8*2 ;sinh(
or a
sbc hl, de
add hl, de ;essentially, cp DE
        jr z, cscToken
;Test the next token
ld hl, $CA*2 ;cosh(
or a
sbc hl, de
add hl, de ;essentially, cp DE
pop hl
ret nz
secToken:
ld hl, secText-tokenHook+smallEditRam-1
        ret
cscToken:
pop hl
ld hl, cscText-tokenHook+smallEditRam-1
ret
cscText:
.db 4, "csc(" ;length, then string
SecToken:
.db 4, "sec("

tokenHookEnd:


Up !

I found this and now I use it, so thank you thepenguin77

TiAddict : to use hooks with Mimas, you must use the length and the hex codes of the ascii catacteres instead of the length and the string.

Code: [Select]

cscText:
.db 4,$63,$73,$63,$28
; instead of
.db 4,"csc("

And I've a question : with your code thepenguin77, how do you define several hooks in one file ?

Couldnt you do this?

.db 4,'c','s','c','('

IIRC, mimas converts characters in single quotes to their ascii values, so this would work: ld a,'q'

Okay, so here is some code I just threw together for Grammer that changes some tokens around:

tokenHook:
     .db $83
     push hl
     ld hl,TokenTable
     ld b,0
TokenSearchLoop:
       ld a,e
       cp (hl)
       inc hl
       jr z,ChkByte2
NotTokenMatch:
       inc hl
       ld c,(hl)
       inc c
       add hl,bc
       ld a,(hl)
       or a
       jr nz,TokenSearchLoop
     pop hl
     ret
ChkByte2:
     ld a,d
     cp (hl)
     jr nz,NotTokenMatch
     ex (sp),hl
     pop hl
     ld de,8478h
     push de
     inc hl
     ld c,(hl)
     inc c \ inc c
     dec hl
     ldir
     pop hl
     ret
NoChange:
TokenTable:
 .db $06,0,8,"lFactor",5
 .db $0C,0,7,"WriteM",$C1
 .db $10,0,6,"ReadW("
 .db $20,0,6,"ReadB("
 .db $28,0,7,"Insert("
 .db $36,0,7,"ClrPart"
 .db $38,0,7,"RunPart"
 .db $3A,0,8,"AddPart("
 .db $3C,0,9,"PartType("
 .db $44,0,5,"Misc("
 .db $58,0,1,5Fh
 .db $BE,0,5,"call "
 .db $38,1,5,"Rect("
 .db $3C,1,5,"Tile("
 .db $3E,1,7,"Sprite("
 .db $40,1,8,"TileMap("
 .db $48,1,9,"Contrast("
 .db $4E,1,9,"ShiftBuf("
 .db $62,1,7,"WriteB("
 .db $70,1,4,"Inv("
 .db $72,1,7,"WriteW("
 .db $A6,1,4,"For "
 .db $B4,1,7,"GetInc("
 .db $BC,1,7,"SetBuf "
 .db $C0,1,8,"SetFont "
 .db $CE,1,8,"MakeVar("
 .db $D0,1,8,"FindVar("
 .db 0
The syntax for the token names is the value of DE (little endian), followed by the name size and then the name. So the last token on that list is E8 (the Get( token). DE will be 1D0h, so I do .db $D0,1
EDIT: Add this to the start of the hook (after .db 83h) so that 2-byte tokens don't interfere:
     ld a,b
     or a
     ret nz


Oh, yes, that will only work in an APP. For a program, just copy the hook and table to RAM. You will need to play with pointers, though, too.

I'm really a beginner in ASM, but I think that put this code after :ld hl,tokenHook
ld de,smallEditRam
ld bc,tokenEnd-tokenHook
ldir
ld a,1
ld hl,smallEditRam
bcall _enableTokenHook
retWill work, right ?

EDIT : no, it doesn't work ... what should I do ?

No, I can do this, but I don't know how to rename much tokens.

Doesn't work
But I don't know how to copy the token table to smallEditRam, my code seems not work