I think it would be possible with assembly, but it's fairly advanced (unless I'm over complicating things, which is quite possible... )

I believe you could write a program that would install an interrupt hook that will run in the OS when the [PRGM] button is pressed, and execute your own "program menu". Unfortunately, I'm no expert when it comes to interrupts and hooks 

There are three ways I see to go about this: the two easier ones are either the menu hook or the raw key hook.

The menu hook gets called rather frequently when the menu shows up so you might be able to tweak some stuff (set a breakpoint at the start of your hook (after checking for the correct menu) and look around at what has been set up. This is your best bet for tweaking stuff). The raw key hook would basically be you completely changing the function of the program button. I don't know what your plans are, but this is probably the more difficult of the two because you'd have to make your own menu.

If this is the first time you've used hooks, you should check out my hook guide.


Now, the third option is patching the OS. This is pretty tricky actually and probably isn't the option you want to use. But, of course, we don't know what you want to change.

Finally, you've sadly picked the worst menu to change. The program menu is generated dynamically and is a pain to mess around with.

I would quit programming on-calc and use spasm or brass to assemble with and TilEm2 or WabbitEmu (or even PindurTI) to debug. What exactly do you need help with? Setting up the hook? Coding the menu?

EDIT: From the information on WikiTI i just built a quick program (well, app) to install a raw keyhook to check if Prgm was pressed.
To assemble you'll need ti83plus.inc and app.inc, attached. To assemble you might need to download spasm.
#include "ti83plus.inc"
#include "app.inc"

defpage(0, "PrgmMenu")

start:
bcall(_ClrLCDFull)
bit rawKeyHookActive,(iy+sysHookFlg) ;check if hook is active
jr z,activate
;uninstall hook
ld hl,uninstalledTxt
call AppPutS
bcall(_ClrRawKeyHook)
jr quit
;install hook
activate:
ld hl,installedTxt
call AppPutS
in a,(6) ;load the current page into a
ld hl,prgmMenu
bcall(_SetGetKeyHook)
quit:
call pause
bjump(_JForceCmdNoChar) ;ciao!

AppPutS:
ld a,(hl)
or a
ret z
bcall(_PutC)
inc hl
jr AppPutS

pause:
xor a
out (1),a
push af
pop af ;delay for slower calcs
in a,(1)
inc a
jr nz,$-3 ;wait for all keys to be released
in a,(1)
inc a
jr z,$-3 ;wait for a key to be pressed
ret

installedTxt:
.db "Hook Installed!",0

uninstalledTxt:
.db "Hook Uninstalled",0

prgmMenu:
.db 83h ;required byte
cp kPrgm ;check if [Prgm] was pressed
ret nz
ld hl,noMenuTxt
call AppPutS
call pause
bcall(_ClrScrn)
bcall(_HomeUp)
xor a ;set z to ignore keypress
ret

noMenuTxt:
.db "Haha! Now you   have no menu!",0
I'd never used hooks before, either, but the information's out there

Thanks chickendude, that's what pretty much what I was asking for. But one question, why did you write your own print string function rather than use putS?

Also, thepenguin, did just you make that suite or did you have it already? If you just made it you are amazing. Just a small problem though, I had to download a newer version of spasm from the wabbit website for it to work.

I just made it. It's not much more than a few folders with 3 .bat files. After a while you can write this stuff without really thinking about it.

Btw, the backups folder is there in case you accidentally delete a file. I've done it before and it sucks. It's not the best backup system, but it works.